/*
	シンプルプリローダー(SWF6以降用)

	■ローダーの取り付け方■
	○ParaFla! の場合
	「プロジェクトのプロパティ」で「ID:9999の画像ファイルをロード画面にする」にチェックし、
	ID:9999のスプライトの中の1フレーム目にフレームアクションとしてこのスクリプトを記述します。
	メインイベントのはじめには[何もしない:1][画像消去:0]を入れてください。

	○Suzuka の場合
	レイヤーリストにフォルダを作り、フォルダ内にスプライトを「開始フレーム1」「フレームカウント2」にして配置し、
	そのスプライトの中の1フレーム目にフレームアクションとしてこのスクリプトを記述します。

	スクリプトを外部ファイルとして置きたい場合はこのスクリプトをテキストファイルとして保存し、
	スプライトのフレームアクションに次のように記述してください。
	""の中にはスクリプトのテキストファイルのファイル名（パス）を入力してください。
		#FILE "ファイル名";

	ローダーはswfのサイズに合わせて自動調整されますが、
	サイズが小さすぎると潰れてしまうので、250×250px以上のサイズを強く推奨します。

	■その他■
	このスクリプトを使用して発生したいかなる損害は、作者は責任を負いません。
	改造は自由ですが、自己責任で行ってください。
	何かありましたら、下記サイトにご連絡下さい。

	2007/12/19

	HynWi
	http://www.geocities.jp/para_core/index.html
*/

//-----<設定項目>------------------------------------------------------------------------------------------*

this.mainmsg = "" ;
				//ローダー上部に表示するメッセージ
this.color_type = 1 ;		//配色のタイプ(0:自分で決める/1:モノクロ/2:ブルー/3:レッド/4:グリーン)

//＊＊＊＊＊↑で0に設定した場合は以下を編集する ＊＊＊＊＊

	this.back = 0x000000 ;		//背景色
	this.s_color = 0xFFFFFF ;	//ウィンドウの色
	this.main_tx_c = 0xFFFFFF ;	//文字色
	this.tx_color = 0x000000 ;	//ボタン文字色
	this.tx_l_co = 0xCCCCFF ;	//ボタンのオンマウス時文字色

//＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊

this.autoplay = 0 ;		//ロード終了後自動で再生を開始する:1
this.menu = 0 ;			//右クリックメニューを非表示にする:1
this.ql_but = 1 ;		//画質変更ボタンを表示しない:0
this.preview = 0 ;		//ロード画面をシミュレートする:1
this.bcount = 50 ;		//(previewが1の場合)1フレームで読み込むシミュレートバイト数

//-----<設定ここまで 以下構成部>---------------------------------------------------------------------------*

total = _root.getBytesTotal();
loaded = 0;
load_c = 0;

//配色設定
if(color_type == 1){
	this.back = 0x000000 ;
	this.s_color = 0xFFFFFF ;
	this.main_tx_c = 0xFFFFFF ;
	this.tx_color = 0x000000 ;
	this.tx_l_co = 0xCCCCFF ;
}else if(color_type == 2){
	this.back =  0x99CCFF ;
	this.s_color = 0x3366FF ;
	this.main_tx_c = 0x3300FF ;
	this.tx_color = 0x000000 ;
	this.tx_l_co = 0xCCCCFF ;
}else if(color_type == 3){
	this.back =  0xFFCC99 ;
	this.s_color = 0xFF6600 ;
	this.main_tx_c = 0xFF0000 ;
	this.tx_color = 0x000000 ;
	this.tx_l_co = 0xCCCCFF ;
}else if(color_type == 4){
	this.back =  0x99FF99 ;
	this.s_color = 0x00CC00 ;
	this.main_tx_c = 0x006600 ;
	this.tx_color = 0x000000 ;
	this.tx_l_co = 0xCCCCFF ;
}

//メッセージ表示
	m_msg = this.createEmptyMovieClip("mnmsg",8);
	m_msg.createTextField("tx", 0, 0, Math.floor(Stage.height / 8), Stage.width, 30);
		m_msg.fm = new TextFormat();
		m_msg.fm.size = 15;
		m_msg.fm.color = main_tx_c;
		m_msg.fm.bold = true;		//太字にする
		m_msg.fm.italic = false;	//斜体にする
		m_msg.fm.align = "center";	//配置
	m_msg.tx.selectable = false;
	m_msg.tx.text = this.mainmsg;
	m_msg.tx.setTextFormat(m_msg.fm);

//背景
bg = createEmptyMovieClip("background",1);
	bg.clear();
	bg.lineStyle();
	bg.beginFill(back);
		bg.moveTo(0,0);
		bg.lineTo(Stage.width,0);
		bg.lineTo(Stage.width,Stage.height);
		bg.lineTo(0,Stage.height);
		bg.lineTo(0,0);
	bg.endFill();

//進行バー
phl = createEmptyMovieClip("progress",7);
phl.m = 0;

sw6 = Math.floor(Stage.width / 6);
sh3 = Math.floor(Stage.height / 3);

pb = this.createEmptyMovieClip("p_bar",2);
	pb.clear();
	pb.lineStyle(1, s_color, 100);
		pb.moveTo(sw6, sh3);
		pb.lineTo(sw6 * 5, sh3);
		pb.lineTo(sw6 * 5, sh3 + 20);
		pb.lineTo(sw6, sh3 + 20);
		pb.lineTo(sw6, sh3);

//読み込み進度
	im = this.createEmptyMovieClip("infomes",3);
	im.createTextField("tx", 0, 0, Math.floor(Stage.height / 2) + 40, Stage.width, 30);
		im.fm = new TextFormat();
		im.fm.size = 15;
		im.fm.color = main_tx_c;
		im.fm.bold = true;
		im.fm.align = "center";
	im.tx.selectable = false;
	im.tx.text = "";
	im.tx.setTextFormat(im.fm);

//画質変更ボタン
	if(ql_but >= 1){
		sqw = createEmptyMovieClip("q_w",4);
			sqw._y = Stage.height - 30;
			sqw.clear();
			sqw.lineStyle();
			sqw.beginFill(s_color);
				sqw.moveTo(0, 0);
				sqw.lineTo(Stage.width, 0);
				sqw.lineTo(Stage.width, 30);
				sqw.lineTo(0, 30);
				sqw.lineTo(0, 0);
			sqw.endFill();

		hb = sqw.createEmptyMovieClip("qh_b",0);
		hb.createTextField("h_sb", 6, 0, 0, 45, 25);
			hb.h_fm = new TextFormat();
			hb.h_fm.size = 15;
			hb.h_fm.color = tx_color;
			hb.h_fm.bold = true;
		hb.h_sb.selectable = false;
		hb.h_sb.text = "HIGH";
		hb.onPress = function(){button_nf(0);};
		hb.onRelease = hq;
		hb.onReleaseOutside = function(){button_nf(0);};
		hb.onRollOver = function(){hb.h_fm.color = tx_l_co; hb.h_sb.setTextFormat(hb.h_fm);};
		hb.onRollOut = function(){button_nf(0);};
		hb.h_sb.setTextFormat(hb.h_fm);

		mb = sqw.createEmptyMovieClip("qm_b",1);
		mb._x = 55;
		mb.createTextField("h_sb", 6, 0, 0, 80, 25);
			mb.h_fm = new TextFormat();
			mb.h_fm.size = 15;
			mb.h_fm.color = tx_color;
			mb.h_fm.bold = true;
		mb.h_sb.selectable = false;
		mb.h_sb.text = "MEDIUM";
		mb.onPress = function(){button_nf(1);};
		mb.onRelease = mq;
		mb.onReleaseOutside = function(){button_nf(1);};
		mb.onRollOver = function(){mb.h_fm.color = tx_l_co; mb.h_sb.setTextFormat(mb.h_fm);};
		mb.onRollOut = function(){button_nf(1);};
		mb.h_sb.setTextFormat(mb.h_fm);

		lb = sqw.createEmptyMovieClip("ql_b",2);
		lb._x = 145;
		lb.createTextField("h_sb", 6, 0, 0, 45, 25);
			lb.h_fm = new TextFormat();
			lb.h_fm.size = 15;
			lb.h_fm.color = tx_color;
			lb.h_fm.bold = true;

		lb.h_sb.selectable = false;
		lb.h_sb.text = "LOW";
		lb.onPress = function(){button_nf(2);};
		lb.onRelease = lq;
		lb.onReleaseOutside = function(){button_nf(2);};
		lb.onRollOver = function(){lb.h_fm.color = tx_l_co; lb.h_sb.setTextFormat(lb.h_fm);};
		lb.onRollOut = function(){button_nf(2);};
		lb.h_sb.setTextFormat(lb.h_fm);
	}

//メニュー非表示設定
	if(menu == 1){Stage.showMenu = false;}else{Stage.showMenu = true;}

	//ロード表示
	vm = createEmptyMovieClip("vmes",5);
		vm.createTextField("tx", 0, 0, Math.floor(Stage.height / 2), Stage.width, 30);
			vm.fm = new TextFormat();
			vm.fm.size = 18;
			vm.fm.color = main_tx_c;
			vm.fm.bold = true;
			vm.fm.align = "center";
		vm.tx.selectable = false;
		vm.tx.text = "NOW LOADING...";
		vm.tx.setTextFormat(vm.fm);

this.onEnterFrame = function(){

	//ロード処理
	if(preview >= 1){
		if(loaded < total){
			loaded += bcount;
		}else if(loaded >= total){
			loaded = total;
		}
	}else if(preview == 0){
		loaded = _root.getBytesLoaded();
	}

	im.tx.text = loaded + " Bytes / " + total + " Bytes";
	im.tx.setTextFormat(im.fm);

	//読み込み待機
	if(loaded < total){
		if(_root._CurrentFrame > 1){
			_root.gotoAndStop(1);
		}
	}else if(load_c == 0){
		_root.gotoAndStop(1);
		if(autoplay >= 1){
			fin();
		}else{
			start();
		}
		load_c = 1;
	}else{}

	//画質表示
	if(ql_but >= 0){
		if(_root._quality.toLowerCase() == "high"){
			hb.h_fm.underline = true; mb.h_fm.underline = false; lb.h_fm.underline = false;
			hb.h_sb.setTextFormat(hb.h_fm); mb.h_sb.setTextFormat(mb.h_fm); lb.h_sb.setTextFormat(lb.h_fm);
		}else if(_root._quality.toLowerCase() == "medium"){
			hb.h_fm.underline = false; mb.h_fm.underline = true; lb.h_fm.underline = false;
			hb.h_sb.setTextFormat(hb.h_fm); mb.h_sb.setTextFormat(mb.h_fm); lb.h_sb.setTextFormat(lb.h_fm);
		}else if(_root._quality.toLowerCase() == "low"){
			hb.h_fm.underline = false; mb.h_fm.underline = false; lb.h_fm.underline = true;
			hb.h_sb.setTextFormat(hb.h_fm); mb.h_sb.setTextFormat(mb.h_fm); lb.h_sb.setTextFormat(lb.h_fm);
		}
	}


//読み込み表示
	if(loaded < total){
		phl.clear();
		phl.lineStyle(1, s_color, 100);
		phl.beginFill(s_color);
			phl.moveTo(sw6 + 2, sh3 + 2);
			phl.lineTo(sw6 + Math.floor(sw6 * 4 * (loaded / total)) - 2, sh3 + 2);
			phl.lineTo(sw6 + Math.floor(sw6 * 4 * (loaded / total)) - 2, sh3 + 18);
			phl.lineTo(sw6 + 2, sh3 + 18);
			phl.lineTo(sw6 + 2, sh3 + 2);
		phl.endFill();

	}else if(loaded >= total && phl.m == 0){
		progress_c();
		phl.m = 1;
	}
};

function progress_c(){
		phl.clear();
		phl.lineStyle(1, s_color, 100);
		phl.beginFill(s_color);
			phl.moveTo(sw6 + 2, sh3 + 2);
			phl.lineTo(sw6 * 5 - 2, sh3 + 2);
			phl.lineTo(sw6 * 5 - 2, sh3 + 18);
			phl.lineTo(sw6 + 2, sh3 + 18);
			phl.lineTo(sw6 + 2, sh3 + 2);
		phl.endFill();
};

function button_nf(n){
	if(n == 0){
		hb.h_fm.color = tx_color; hb.h_sb.setTextFormat(hb.h_fm);
	}else if(n == 1){
		mb.h_fm.color = tx_color; mb.h_sb.setTextFormat(mb.h_fm);
	}else if(n == 2){
		lb.h_fm.color = tx_color; lb.h_sb.setTextFormat(lb.h_fm);
	}
n.color = 0xCCCCFF; t.setTextFormat(n);
};

function hq(){_root._quality = "high";};
function mq(){_root._quality = "medium";};
function lq(){_root._quality = "low";};

function lg(){pb.pfm.color = tx_l_co; pb.tx.setTextFormat(pb.pfm);};
function nr(){pb.pfm.color = tx_color; pb.tx.setTextFormat(pb.pfm);};

function start(){
	vm.tx.text = "";

	//スタートボタン描画
	pb = createEmptyMovieClip("p_button",6);
	pb._x = Math.floor(Stage.width / 2) - 40;
	pb._y = Math.floor(Stage.height / 2);
		pb.clear();
		pb.lineStyle();
		pb.beginFill(s_color);
			pb.moveTo(0, 0);
			pb.lineTo(80, 0);
			pb.lineTo(80, 25);
			pb.lineTo(0, 25);
		pb.endFill();

	pb.createTextField("tx", 1, 0, 0, 80, 25);
		pb.pfm = new TextFormat();
		pb.pfm.size = 15;
		pb.pfm.color = tx_color;
		pb.pfm.bold = true;
		pb.pfm.align = "center";
	pb.tx.selectable = false;
	pb.tx.text = "START";
	pb.onPress = nr;
	pb.onRelease = fin;
	pb.onReleaseOutside = nr;
	pb.onRollOver = lg;
	pb.onRollOut = nr;
	pb.tx.setTextFormat(pb.pfm);
};

function fin(){
	//再生開始処理
	_root.play();
};